/HEADER
DATA ACCESS CORPORATION 			    INVENTORY MOVEMENT REPORT
=============================================================================

/SUBHEADER2
VEN: _0.  ITEM: _______________    DSCR: ___________________________________
      STORE ID: _______________     QTY: ___.  PRICE $______.__

	QTY-SOLD   INVOICE	  PRICE     AMOUNT	 COST	  PROFIT
/BODY RESIDENT
	_______.   _______   ___,___.__ ___,___.__ ___,___.__ ___,___.__
/SUBTOTAL2 
	--------			 ---------  ---------  ---------
	_______.			___,___.__ ___,___.__ ___,___.__
------------------------------------------------------------------------------
/SUBTOTAL1 
		VENDOR TOTALS:		___,___.__ ___,___.__ ___,___.__
==============================================================================

/TOTAL 
   
			    GRAND TOTALS

		AMOUNT		 COST		PROFIT
	  _$___,___.__	_$,___,___.__	 _$____,___.__
=============================================================================
/*
//This report is a little more complex.  It uses two data files, inventory
//and inventory transactions (items).  Two levels of break points are
//used to show all parts sold by vendor and then by part_id.

	OPEN INVT
	OPEN ITEMS INDEX.2	//open the items file and buffer index 2
	OUTFILE 		//direct the output to the printer (default)

	REPORT ITEMS BY INDEX.2 BREAK ITEMS.VENDOR ITEMS.PART_ID

//this report will print all inventory transactions subtotaled by
//vendor and then by inventory part

SECTION HEADER
	OUTPUT HEADER		//print the header at the top of
				//all pages of the report

SECTION SUBHEADER2		//this section will be executed
	PRINT INVT.VENDOR	//when the vendor id changes
	PRINT INVT.VENDOR_PART_ID
	PRINT INVT.DESCRIPTION
	PRINT INVT.PART_ID
	PRINT INVT.QUANTITY
	PRINT INVT.LIST_PRICE
	OUTPUT SUBHEADER2
SECTION BODY			//print for each inventory part
	PRINT ITEMS.QUANTITY
	PRINT ITEMS.INVOICE
	PRINT ITEMS.PRICE
	PRINT ITEMS.AMOUNT
	PRINT ITEMS.COST
	PRINT (ITEMS.AMOUNT-ITEMS.COST)  //calculate and print the profit
	OUTPUT BODY
SECTION SUBTOTAL2		//for each invt part print the accumulated:
	SUBTOTAL BODY.1 	//qty sold
	SUBTOTAL BODY.4 	//amount
	SUBTOTAL BODY.5 	//cost
	SUBTOTAL BODY.6 	//profit
	OUTPUT SUBTOTAL2
SECTION SUBTOTAL1			//for each vendor print
	SUBTOTAL SUBTOTAL2.2		//total amount
	SUBTOTAL SUBTOTAL2.3		//total cost
	SUBTOTAL SUBTOTAL2.4		//total profit 
	OUTPUT SUBTOTAL1
SECTION TOTAL				//grand totals for this report:
	SUBTOTAL SUBTOTAL1.1		//amount
	SUBTOTAL SUBTOTAL1.2		//cost
	SUBTOTAL SUBTOTAL1.3		//profit
	OUTPUT TOTAL
REPORTEND
ABORT

OTAL SUBTOTAL1.1		//amount
	SUBTOTAL SUBTOTAL1.2		//cost
	SUBTOTAL SUBTOTA